Создание визуальных компонент для Lazarus

Компоненты или элементы управления являются именно теми "кирпичиками", из которых и позволяют создавать программы интегрированные средства быстрой разработки. Lazarus также придерживается этой концепции. Однако, в отличие от VB и подобно Delphi, Lazarus абсолютно самодостаточен в вопросе создания программистами своих собственных компонент.

Постановка задачи

В действительности, создать свой собственный компонент очень легко. Настолько легко, что не имеет смысла описывать этот процесс на простом примере. Поэтому, поставим себе некоторую нетривиальную задачу. Вот, к примеру, имеется стандартный элемент управления TStatusBar, который представляет собой относительно несложную панель состояния, которая располагается вдоль нижней границы окна. Его можно разбить на несколько панелей, в каждой из которых выводить какие-либо сообщения. К сожалению, ничего кроме текста эти панели отображать не умеют. Что там можно ещё отображать? Например, неплохо было бы разместить ProgressBar, чтобы не просто сообщить пользователю о начале какого либо продолжительного процесса, а постоянно держать его в курсе текущего состояния. Вот этим и займёмся.

Слишком уж мудрить не будем. В качестве предка возьмём TStatusBar и предусмотрим всего пару дополнительных свойств: одно для непосредственного доступа к встроенному ProgressBar, чтобы можно было им управлять, а другое - для указания, в какой из панелей строки состояния будет отображаться ProgressBar.

Скачать архив с уже готовым комплектом файлов компонента можно здесь.

Создание пакета

Так как для добавления компонентов в палитру компонент Lazarus используются пакеты, сначала создадим новый пакет. Для этого в меню "Файл" выберем пункт "Создать". В левой части появившегося окна выберем "Standard Package" и нажмём кнопку "OK", как показано на рисунке:

На экране возникнет окно управления пакетом. Сохраним наш новый и пока пустой пакет в отдельном каталоге под именем, например, prgstatusbarlaz.lpk. Теперь добавим новый компонент. Вообще говоря, один пакет может содержать сколько угодно компонентов, но нам пока достаточно одного. Нажмите кнопку "Добавить" и в появившейся форме перейдите на вкладку "Новый компонент". Заполните все поля примерно так, как показано на рисунке:

Нажмите кнопку "OK" и новый файл с заготовкой компонента будет добавлен в пакет. Также, поскольку мы создаём визуальный компонент, будет добавлена зависимость от пакета LCL. Чтобы приступить непосредственно к разработке компонента, двойным щелчком по имени модуля откройте его в редакторе исходного кода. То, что Вы увидите будет являться результатом автоматической генерации кода на основе сделанных настроек и уже может быть установлено как пользовательский элемент управления, который пока просто дублирует своего родителя.

Разработка компонента

Для начала, добавим необходимые свойства. Для этого в секции published напечатаем следующее:

    property ProgressBar: TProgressBar read;
    property ProgressBarPanel: Integer; 

    constructor Create(TheOwner: TComponent); override;
    destructor Destroy; override;

  FProgressBarPanel := -1;

  FProgressBar := TProgressBar.Create(Self);
  Include(FProgressBar.ComponentStyle, csSubComponent);

  FProgressBar.Parent := self;
  FProgressBar.Top := 0;
  FProgressBar.Height := 0;
  FProgressBar.Width := 0;
  FProgressBar.Left := 0;

  FIsLoaded := False;

Теперь перейдём к процедуре SetProgressBarPanel установки значения свойства ProgressBarPanel. Сгенерированного автоматически кода явно недостаточно, потому, что простое на первый взгляд присвоение значения свойству на самом деле связано со значительным количеством проверок и других действий. Итак, по-порядку.

  if FProgressBarPanel=AValue then Exit;
  if not FIsLoaded then // Это происходит загрузка свойств из потока
  begin
    FProgressBarPanelTemp := AValue; // Сохраним свойство, чтобы потом присвоить его в Loaded.
    Exit; // Следующая проверка не имеет смысла, пока панели не загружены из потока.
  end;
  if (AValue >= self.Panels.Count) then Exit;

Единственный способ выйти из этой неприятной ситуации - временно сохранить значение, которое мы собираемся установить. Только когда все свойства компонента будут загружены, а панели созданы, мы сможем присвоить значение свойству ProgressBarPanel. Для этого нам надо переопределить метод Loaded. Наберём в секции Protected декларацию

  procedure Loaded; override;

procedure TPrgStatusBar.Loaded;
begin
  inherited Loaded;
  FIsLoaded := True;
  SetProgressBarPanel(FProgressBarPanelTemp);
end;

Теперь, когда учтены все нюансы поведения программы, закончим работу с методом SetProgressBarPanel, добавив довольно бесхитростный код, который будет размещать ProgressBar внутри выбранной панели. В итоге должно получиться следующее:

procedure TPrgStatusBar.SetProgressBarPanel(const AValue: Integer);
var
  i: Integer;
  L: Longint;
begin
  if FProgressBarPanel=AValue then Exit;
  if not FIsLoaded then // Это происходит загрузка свойств из потока
  begin
    FProgressBarPanelTemp := AValue; // Сохраним свойство, чтобы потом присвоить его в Loaded.
    Exit; // Следующая проверка не имеет смысла, пока панели не загружены из потока.
  end;
  if (AValue >= self.Panels.Count) then Exit;
  if AValue = -1 then
  begin
    FProgressBar.Top := 0;
    FProgressBar.Height := 0;
    FProgressBar.Width := 0;
    FProgressBar.Left := 0;
    FProgressBarPanel := -1;
    Exit;
  end;
  FProgressBar.Top := 2;
  FProgressBar.Height := self.Height-2;
  L := 0;
  for i := 1 to AValue do
    L := L + self.Panels[i-1].Width;
  if AValue = 0 then
  begin
    FProgressBar.Left := 0;
  	FProgressBar.Width := self.Panels[AValue].Width;
  end
  else
  begin
    FProgressBar.Left := L + 2;
  	FProgressBar.Width := self.Panels[AValue].Width - 2;
  end;
  FProgressBarPanel:=AValue;
end;

destructor TPrgStatusBar.Destroy;
begin
  FProgressBar.Free;
  FProgressBar := nil;
  inherited Destroy;
end;

    property ProgressBarPanel: Integer read FProgressBarPanel write SetProgressBarPanel default 1;

procedure Register;
begin
  RegisterComponents('Misc',[TPrgStatusBar]);
end;

Пиктограммы

Чтобы отличать компоненты друг от друга в палитре компонент Lazarus, разработчики стараются сделать их значки как можно более уникальными. Кроме того, с их помощью стараются показать назначение компонента. Давайте и мы сделаем иконку для нашего нового компонента. Правила очень простые:

1. Надо создать изображение размером максимум 23x23 пиксела и сохранить его в формате XPM. Имя файла должно совпадать с именем класса компонента (регистр не имеет значения).
2. Все изготовленные файлы с рисунками (в нашем случае всего один) нужно скомпилировать в ресурсный файл с помощью утилиты lazres, которая находится в каталоге tools (её саму сначала надо собрать, запустив make в этом каталоге).

   C:\lazarus\tools\lazres.exe prgstatusbarlaz.lrs tprgstatusbar.xpm
   

3. Теперь надо подключить файл ресурсов в секции инициализации модуля компонента:

   initialization
     {$I prgstatusbarlaz.lrs}
                               

Тестовая программа

Для проверки работы нашего нового компонента установим пакет и создадим простейшую программу тестирования. В главной форме разместим нашу модернизированную строку состояния, в которой определим 4 панели, кнопку и таймер. Примерно так, как показано на рисунке:

unit Unit1;

{$mode objfpc}
{$H+}

interface

uses
  Classes, SysUtils, LResources, Forms, Controls, Graphics, Dialogs, ComCtrls,
  Buttons, ExtCtrls, PrgStatusBar;

type

  { TForm1 }

  TForm1 = class(TForm)
    PrgStatusBar1: TPrgStatusBar;
    SpeedButton1: TSpeedButton;
    Timer1: TTimer;
    procedure SpeedButton1Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
  end;

var
  Form1: TForm1;

implementation

{ TForm1 }

procedure TForm1.SpeedButton1Click(Sender: TObject);
begin
  PrgStatusBar1.ProgressBar.Position := 0;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  PrgStatusBar1.ProgressBar.StepIt;
end;

initialization
  {$I unit1.lrs}

end.